Example : Chemical Reactions{ view comments }
TITLE
'Open Tube Chemical Reactor with Strip Heater'
VARIABLES
Temp (threshold=0.1)
C (threshold=0.1)
DEFINITIONS
Lz = 1
r1=1
heat=0
gamma = 16
beta = 0.2
betap = 0.3
BI = 1
T0 = 1
TW = 0.92
RC = (1-C)*exp(gamma-gamma/Temp) { the very nasty reaction rate }
xev=0.966 { some plot points }
yev=0.259
INITIAL VALUES
Temp=T0
C=0
EQUATIONS
Temp: div(grad(Temp)) + heat + betap*RC = dt(Temp)
C: div(grad(C)) + beta*RC = dt(C)
BOUNDARIES
REGION 1
start (0,0)
natural(Temp) = 0
natural(C) = 0
line to (r1,0) { a mirror plane on X-axis }value(Temp)=1.2 { "Strip Heater" at fixed temperature }
natural(C)=0 { ... and no mass flow }
arc(center=0,0) angle 5 { ... on outer arc }natural(Temp)=BI*(TW-Temp) { convective cooling }
natural(C)=0 { ... and no mass flow }
arc(center=0,0) angle 85 { ... on outer arc }natural(Temp) = 0
natural(C) = 0
line to close { another mirror plane on Y-axis }
TIME 0 to 1 { Specify the time range }
PLOTS
for cycle=10 { watch the fast events by cycle }
grid(x,y)
contour(Temp)
contour(C) as "Completion"
for t= 0.2 by 0.05 to 0.3 { show some surfaces during burn }
surface(Temp)
surface(C) as "Completion"
HISTORIES
history(Temp) at (0,0) (xev/2,yev/2) (xev,yev) (yev/2,xev/2) (yev,xev)
history(C) at (0,0) (xev/2,yev/2) (xev,yev) (yev/2,xev/2) (yev,xev) as "Completion"
END