{ VIBAR.PDE }
title "Vibrating Bar - Modal Analysis"
select
modes=8
cubic { Use Cubic Basis }
errlim = 0.005
variables
U { X-displacement }
V { Y-displacement }
definitions
L = 1 { Bar length }
hL = L/2
W = 0.1 { Bar thickness }
hW = W/2
nu = 0.3 { Poisson's Ratio }
E = 20 { Young's Modulus for Steel x10^11(dynes/cm^2) }
G = 0.5*E/(1+nu)
rho = 7.8 { Density (g/cm^3) }
{ plane strain coefficients }
E1 = E/((1+nu)*(1-2*nu))
C11 = E1*(1-nu)
C12 = E1*nu
C22 = E1*(1-nu)
C33 = E1*(1-2*nu)/2
Sx = [C11*dx(U) + C12*dy(V)] { Stresses }
Sy = [C12*dx(U) + C22*dy(V)]
Txy = C33*[dy(U) + dx(V)]
mag=0.05
initial values
U = 0
V = 0
equations { define the displacement equations }
U: dx[C11*dx(U) + C12*dy(V)] + dy[C33*(dy(U) + dx(V))] + lambda*rho*U = 0
V: dx[C33*(dy(U) + dx(V))] + dy[C12*dx(U) + C22*dy(V)] + lambda*rho*V = 0
boundaries
region 1
start (0,-hW)
load(U)=0 { free boundary on bottom, no normal stress }
load(V)=0
line to (L,-hW)
value(U) = 0 { clamp the right end }
line to (L,0) point value(V) = 0
line to (L,hW)
load(U)=0 { free boundary on top, no normal stress }
load(V)=0
line to (0,hW)
load(U) = 0
load(V) = 0 { apply distributed load to Y-displacement equation }
line to close
monitors
grid(x+mag*U,y+mag*V) as "deformation" { show final deformed grid }
plots
grid(x+mag*U,y+mag*V) as "deformation" { show final deformed grid }
contour(U) as "X-Displacement(M)"
contour(V) as "Y-Displacement(M)"
end