Transfer_In

{  TRANSFER_IN.PDE  }

{

  This problem demonstrates the use of the TRANSFER facility to import

  temperatures from TRANSFER_OUT.PDE as the source of thermal expansion

  driving a stress calculation.

  TRANSFER_OUT.PDE must be run before running this problem.

}

Title 'Testing the TRANSFER input function'

select

   painted             { paint all contour plots }

variables

   U

   V

definitions

   nu = 0.3            { define Poisson's Ratio }

   E  = 21             { Young's Modulus x 10**-11 }

   G  = E/(1-nu**2)

   C11 = G

   C12 = G*nu

   C22 = G

   C33 = G*(1-nu)/2

   alpha = 1e-3

   b = G*alpha*(1+nu)

  { HERE IS THE TRANSFER INPUT FUNCTION: }

   transfer('transfer.dat',Temp,Kxfer)

   Sxx = C11*dx(U) + C12*dy(V) - b*Temp

   Syy = C12*dx(U) + C22*dy(V) - b*temp

   Sxy = C33*(dy(U) + dx(V))

initial values

   U = 0

   V = 0

equations

    U:        dx[Sxx] + dy(Sxy)  = 0

    V:        dy[Syy] + dx(Sxy) = 0

constraints

    integral(u) = 0

    integral(v) = 0

    integral(dx(v)-dy(u)) = 0

boundaries

    Region 1

       start "OUTER" (0,0)

       natural(U)=0 value(V)=0

       line to(1,0)

       natural(U)=0 natural(V)=0       { free outer boundary }

       arc (center=0,0) to (0,1)

       value(U)=0 natural(V)=0

       line to close

       natural(U)=0 natural(V)=0       { free inner boundary }

       start "INNER" (0.4,0.2)

       arc (center=0.4,0.4)

          to (0.6,0.4)

          to (0.4,0.6)

          to (0.2,0.4)

          to close

monitors

     grid(x+100*U,y+100*V)

plots

    contour(Temp)  report(Kxfer)

    grid(x+100*U,y+100*V)

    vector(U,V) as "Displacement"

    contour(U) as "X-Displacement"

    contour(V) as "Y-Displacement"

    contour(Sxx) as "X-Stress"

    contour(Syy) as "Y-Stress"

    surface(Sxx) as "X-Stress"

    surface(Syy) as "Y-Stress"

end