Permanent_Magnet

{  PERMANENT_MAGNET.PDE  }

title 'A PERMANENT-MAGNET PROBLEM'

Variables

   A                      { z-component of Vector Magnetic Potential }

Definitions

   mu

   S = 0                       { current density }

   Px = 0                      { Magnetization components }

   Py = 0

   P = vector(Px,Py)           { Magnetization vector }

   H = (curl(A)-P)/mu          { Magnetic field }

   y0 = 8                      { Size parameter }

Initial values

    A = 0

Equations

    curl(H) + S = 0

Boundaries

   Region 1

     mu = 1

     start(-40,0)

     natural(A) = 0 line to (80,0)

     value(A) = 0   line to (80,80) to (-40,80) to close

   Region 2

     mu = 5000

     start(0,0)

     line to (15,0) to (15,20) to (30,20) to (30,y0) to (40,y0) to (40,40)

               to (0,40) to close

   Region 3        { the permanent magnet }

     mu = 1

     Py = 10

     start (0,0) line to (15,0) to (15,10) to (0,10) to close

Monitors

   contour(A)

Plots

   grid(x,y)

   vector(dy(A),-dx(A)) as 'FLUX DENSITY B'

   vector((dy(A)-Px)/mu, (-dx(A)-Py)/mu) as 'MAGNETIC FIELD H'

   contour(A)  as 'Az MAGNETIC POTENTIAL'

   surface(A)  as 'Az MAGNETIC POTENTIAL'

End