{ PERIODAZ.PDE
This example shows the use of FlexPDE in a problem with azimuthal periodicity.
(See the example PERIODIC.PDE for notes on periodic boundaries.)
In this problem we create a repeated 45-degree segment of a ring.
}
title 'AZIMUTHAL PERIODIC TEST'
Variables
u
definitions
k = 1
an = pi/4 { this is the angular size of the repeated segment }
crot = cos(an) { the sine and cosine needed in the transformation }
srot = sin(an)
H = 0
xc = 1.5
yc = 0.2
rc = 0.1
equations
div(K*grad(u)) + H = 0
boundaries
Region 1
{ this line forms the remote boundary for the later periodic statement }
start(1,0) line to (2,0)
value(u) = 0 arc(center=0,0) to (2*crot,2*srot)
{ The following line segment is periodic under an angular rotation.
The mapping expressions take each point on the line into a corresponding
point in the base line. Note that although all the mapped y-coordinates
will be zero, we give the general expression so that the transformation
will be invertible. }
periodic(x*crot+y*srot, -x*srot+y*crot)
line to (crot,srot)
value(u)=0
arc(center= 0,0) to close
Region 2
H = 1
start(xc-rc,yc) arc(center=xc,yc) angle=360
monitors
grid(x,y)
contour(u)
plots
grid(x,y) contour(u)
end