LaserXC

{ LASERXC.PDE }

{ **************************************************************

   This problem shows a complex heatflow application.

   A rod laser is glued inside a cylinder of copper.

   Manufacturing errors allow the rod to move inside the glue, leaving a

   non-uniform glue layer around the rod.  The glue is an insulator, and

   traps heat in the rod.  The copper cylinder is cooled only on a 60-degree

   portion of its outer surface.

   The laser rod has a temperature-dependent conductivity.

   We wish to find the temperature distribution in the laser rod.

   The heat flow equation is

      div(K*grad(Temp)) + Source = 0.

   We will model a cross-section of the cylinder. While this is a cylindrical

   structure, in cross-section there is no implied rotation out of the

   cartesian plane, so the equations are cartesian.

                               -- Submitted by Luis Zapata

   ************************************************************** }

title "Nd:YAG Rod - End pumped.  200 W/cm3 volume source. 0.005in uropol"

Variables

    temp            { declare "temp" to be the system variable }

definitions

    k = 3              { declare the conductivity parameter for later use }

    krod=39.8/(300+temp)  { Nonlinear conductivity in the rod.(W/cm/K) }

    Rod=0.2            {cm Rod radius}

    Qheat=200          {W/cc, heat source in the rod}

    kuropol=.0019      {Uropol conductivity }

    Qu=0               {Volumetric source in the Uropol}

    Ur=0.005           {Uropol annulus thickness in r dim}

    kcopper=3.0        {Copper conductivity }

    Rcu=0.5            {Copper convection surface radius}

    tcoolant=0.        {Edge coolant temperature}

    ASE=0.             {ASE heat/area to apply to edge, heat bar or mount}

    source=0

Initial values

    temp = 50          { estimate solution for quicker convergence }

equations             { define the heatflow equation }

    div(k*grad(temp)) + source = 0;

boundaries

    Region 1           { the outer boundary defines the copper region }

       k = kcopper

       start (0,-Rcu)

       natural(temp) = -2 * temp               {convection boundary}

       arc(center=0,0) angle 60

       natural(temp) = 0                       {insulated boundary}

              arc(center=0,0) angle 300

              arc(center=0,0) to close

    Region 2           { next, overlay the Uropol in a central cylinder }

       k = kuropol

       start (0,-Rod-Ur) arc(center=0,0) angle 360

    Region 3           { next, overlay the rod on a shifted center }

       k = krod

       Source = Qheat

       start (0,-Rod-Ur/2) arc(center=0,-Ur/2) angle 360

monitors

    grid(x,y) zoom(-8*Ur, -(Rod+8*Ur),16*Ur,16*Ur)

    contour(temp)

plots

    grid(x,y)

    contour (temp)

    contour(temp) zoom(-(Rod+Ur),-(Rod+Ur),2*(Rod+Ur),2*(Rod+Ur))

    contour(temp) zoom(-(Rod+Ur)/4,-(Rod+Ur),(Rod+Ur)/2,(Rod+Ur)/2)

    vector(-k*dx(temp),-k*dy(temp)) as "heat flow"

    surface(temp)

end