{
3D_PYRAMID.PDE
This problem considers the flow of heat in a pyramid-shaped body.
It demonstrates the use of FlexPDE in 3D problems with non-planar
extrusion surfaces.
Note that FEATURE paths are used to delineate discontinuities in the
extrusion surfaces.
}
title '3D Test - Pyramid'
coordinates
cartesian3
select
regrid=off
Variables
u
definitions
k = 0.1
heat = 4
equations
div(K*grad(u)) + heat = 0
extrusion
surface z = 0
surface z = min(1- abs(x),1-abs(y))
boundaries
{ implicit natural(u) = 0 on top and bottom faces }
Region 1
start(-1,-1)
value(u) = 0 { Fixed value on short vertical sides }
line to (1,-1) to (1,1) to (-1,1) finish
{ Features delineate hidden discontinuities in surface slope.
This forces gridding nodes along break lines. }
feature start(-1,-1) line to (1,1)
feature start(-1,1) line to (1,-1)
plots
contour(u) on x=0 { YZ plane intersects peak }
contour(u) on y=0 { XZ plane intersects peak }
contour(u) on z=0.1 { XY plane intersects full outline }
contour(u) on x=0.51 { YZ plane near midpoint of side slope }
contour(u) on y=0.51 { XZ plane near midpoint of side slope }
contour(u) on z=0.8 { XY plane near tip }
end 29810