{
3D_MAGNETRON
MODEL OF A GENERIC MAGNETRON IN 3D
}
TITLE 'Oval Magnet '
COORDINATES
CARTESIAN3
SELECT
ngrid=20
alias(x) = "X(cm)"
alias(y) = "Y(cm)"
alias(z) = "Z(cm)"
VARIABLES
Ax,Ay { assume Az is zero! }
DEFINITIONS
MuMag=1.0 ! Permeabilities:
MuAir=1.0
MuSST=1000
MuTarget=1.0
Mu=MuAir ! default to Air
Pmag = 10000 ! permanent magnet strength
Mz = 0 ! global magnetization variable
B = curl(Ax,Ay,0) ! magnetic field vector
Bxx= -dz(Ay)
Byy= dz(Ax) ! unfortunately, "By" is a reserved word.
Bzz= dx(Ay)-dy(Ax)
EQUATIONS
Ax: dx(dx(Ax)/mu) + dy[(dy(Ax)+Mz)/mu] + dz(dz(Ax)/mu) = 0
Ay: dx[(dx(Ay)-Mz)/mu] + dy(dy(Ay)/mu) + dz(dz(Ay)/mu) = 0
EXTRUSION
SURFACE "Boundary Bottom" Z=-5
SURFACE "Magnet Plate Bottom" Z=0
LAYER "Magnet Plate"
SURFACE "Magnet Plate Top" Z=1
LAYER "Magnet"
SURFACE "Magnet Top" Z=2
SURFACE "Boundary Top" Z=8
BOUNDARIES
Surface "boundary bottom" value (Ax)=0 value(Ay)=0
Surface "boundary top" value (Ax)=0 value(Ay)=0
REGION 1 {Air bounded by conductive box }
START (20,-10)
value(Ax)=0 value(Ay)=0
arc(center=20,0) angle=180
Line TO (-20,10)
arc(center=-20,0) angle=180
LINE to close
LIMITED REGION 2 { Magnet Plate }
LAYER "Magnet Plate" Mu=MuSST
LAYER "Magnet" Mu=MuMag Mz=Pmag
START (20,-8)
arc(center=20,0) angle=180
Line TO (-20,8)
arc(center=-20,0) angle=180
LINE to close
LIMITED REGION 3 { Inner Gap }
LAYER "Magnet"
START (20,-6)
arc(center=20,0) angle=180
Line TO (-20,6)
arc(center=-20,0) angle=180
LINE to close
LIMITED REGION 4 {Inner Magnet }
LAYER "Magnet" Mu=MuMag Mz=-Pmag
START (20,-2)
arc(center=20,0) angle=180
Line TO (-20,2)
arc(center=-20,0) angle=180
LINE to close
MONITORS
grid(y,z) on x=0
grid(x,z) on y=0
grid(x,y) on z=1.01
contour(Ax) on x=0
contour(Ay) on y=0
PLOTS
grid(y,z) on x=0
grid(x,z) on y=0
grid(x,y) on z=1.01
contour(Ax) on x=0
contour(Ay) on y=0
vector(Bxx,Byy) on z=2.01 norm
vector(Byy,Bzz) on x=0 norm
vector(Bxx,Bzz) on y=4 norm
contour(magnitude(Bxx,Byy,Bzz)) on z=2
END