{ 3D_CONTACT.PDE
This problem shows the use of a contact resistance boundary between layers.
The resistance model is applied to the entire boundary surface.
See 3D_CONTACT_REGION.PDE for restriction of the resistance model to a single region.
(This is a modification of problem 3D_BRICKS.PDE).
}
title 'steady-state 3D heat conduction with Contact Resistance'
select
regrid=off { use fixed grid }
coordinates
cartesian3
variables
Tp
definitions
long = 1
wide = 1
K { thermal conductivity -- values supplied later }
Q = 10*exp(-x^2-y^2-z^2) { Thermal source }
initial values
Tp = 0.
equations
div[k*grad(Tp)] + Q = 0 { the heat equation }
extrusion z = -long,0,long { divide Z into two layers }
boundaries
surface 1 value(Tp)=0 { fix bottom surface temp }
surface 2 contact(tp)=jump(tp)/10 { THE CONTACT RESISTANCE }
surface 3 value(Tp)=0 { fix top surface temp }
Region 1 { define full domain boundary in base plane }
layer 1 k=1 { bottom right brick }
layer 2 k=0.1 { top right brick }
start(-wide,-wide)
value(Tp) = 0 { fix all side temps }
line to (wide,-wide) { walk outer boundary in base plane }
to (wide,wide)
to (-wide,wide)
to close
Region 2 { overlay a second region in left half }
layer 1 k=0.2 { bottom left brick }
layer 2 k=0.4 { top left brick }
start(-wide,-wide)
line to (0,-wide) { walk left half boundary in base plane }
to (0,wide)
to (-wide,wide)
to close
monitors
contour(Tp) on z=0.01 as "XY Temp - Upper"
contour(Tp) on z=-0.01 as "XY Temp - Lower"
contour(Tp) on x=0 as "YZ Temp"
contour(Tp) on y=0 as "ZX Temp"
elevation(Tp) from (-wide,0,0) to (wide,0,0) as "X-Axis Temp"
elevation(Tp) from (0,-wide,0) to (0,wide,0) as "Y-Axis Temp"
elevation(Tp) from (0,0,-long) to (0,0,long) as "Z-Axis Temp"
plots
contour(Tp) on z=0.01 as "XY Temp - Upper"
contour(Tp) on z=-0.01 as "XY Temp - Lower"
contour(Tp) on x=0 as "YZ Temp"
contour(Tp) on y=0 as "ZX Temp"
elevation(Tp) from (-wide,0,0) to (wide,0,0) as "X-Axis Temp"
elevation(Tp) from (0,-wide,0) to (0,wide,0) as "Y-Axis Temp"
elevation(Tp) from (0,0,-long) to (0,0,long) as "Z-Axis Temp"
end