3D_Constraint

{  3D_constraint.PDE

This problem demonstrates the specification of region-specific

constraints in 3D.

( This is a modification of problem  3D_BRICKS.PDE)

}

title '3D constraint'

coordinates

   cartesian3

variables

   Tp

definitions

   long = 1

   wide = 1

   K                   

   Q = 10*exp(-x^2-y^2-z^2)              { Thermal source }

   flag22=0        { build a test function for region 2, layer 2 }

   check22 = if flag22>0 then Tp else 0

initial values

   Tp = 0.

equations

   div[k*grad(Tp)] + Q = 0

constraints

   integral(Tp,2,2) = 1           { constrain temperature integral in one compartment }

extrusion

surface "bottom" z = -long

layer 'bottom'

surface "middle" z=0

layer 'top'

surface 'top' z= long        

boundaries

   surface 1 value(Tp)=0        { fix bottom surface temp }

   surface 3 value(Tp)=0        { fix top surface temp }

   Region 1                { define full domain boundary in base plane }

      layer 1 k=1                { bottom right brick }

      layer 2 k=0.1                { top right brick }

      start(-wide,-wide)

        value(Tp) = 0                { fix all side temps }

        line to (wide,-wide)        { walk outer boundary in base plane }

          to (wide,wide)

          to (-wide,wide)

          to close

   Region 2 "Left"                { overlay a second region in left half }

      layer 1 k=0.2                { bottom left brick }

      layer 2 k=0.4  flag22=1        { top left brick }

      start(-wide,-wide)

        line to (0,-wide)                { walk left half boundary in base plane }

          to (0,wide)

          to (-wide,wide)

          to close

monitors

     contour(Tp) on surface z=0  as "XY Temp"

     contour(Tp) on surface x=0  as "YZ Temp"

     contour(Tp) on surface y=0  as "ZX Temp"

     elevation(Tp) from (-wide,0,0) to (wide,0,0)  as "X-Axis Temp"

     elevation(Tp) from (0,-wide,0) to (0,wide,0)  as "Y-Axis Temp"

     elevation(Tp) from (0,0,-long) to (0,0,long)  as "Z-Axis Temp"

plots

     contour(Tp) on z=0  as "XY Temp"

     contour(Tp) on x=0  as "YZ Temp"

     contour(Tp) on y=0  as "ZX Temp"

     summary

                report(integral(Tp,2,2))                { integrals in region 2, layer 2 }

       report(integral(Tp,"Left","Top"))        

       report(integral(check22))

       report "Constraint acts as an energy sink:"

       report(sintegral(normal(-k*grad(Tp))))        { surface integral on total outer surface }

       report(integral(Q)) as "Source Integral"

end