TITLE 'Discrete Ordinates-S2-Mode '

SELECT
gridlimit=1
ngrid=5
modes=1

VARIABLES
e1, e2, e3, e4      { flux in four directions}

DEFINITIONS
sigt=1
sigs=1
w=0.25
mu=0.57735
nu=0.57735
a=2.0       { half of square side}
phi=w*(e1+e2+e3+e4)                     { angle integrated flux }

EQUATIONS   { equations for angular fluxes }
e1: div(mu*e1,nu*e1)+sigt*e1-sigs*phi*lambda=0
e2: div(-mu*e2,nu*e2)+sigt*e2-sigs*phi*lambda=0
e3: div(-mu*e3,-nu*e3)+sigt*e3-sigs*phi*lambda=0
e4: div(mu*e4,-nu*e4)+sigt*e4-sigs*phi*lambda=0

BOUNDARIES

 REGION 1 'box'
 START(-a,-a)
  VALUE(e1)=0 VALUE(e2)=0 LINE TO(a,-a)     {incoming flux zero along the boundary}
  VALUE(e2)=0 VALUE(e3)=0 LINE TO(a,a)      {incoming flux zero along the boundary}
  VALUE(e3)=0 VALUE(e4)=0 LINE TO(-a,a)     {incoming flux zero along the boundary}
  VALUE(e4)=0 VALUE(e1)=0 LINE TO(-a,-a)   {incoming flux zero along the boundary}


 PLOTS
 CONTOUR(Phi)
 ELEVATION(Phi) FROM (-a,-a) to (a,-a)
 ELEVATION(Phi) FROM (a,-a) to (a,a)
 ELEVATION(Phi) FROM (a,a) to (-a,a)
 ELEVATION(Phi) FROM (-a,a) to (-a,-a)
 ELEVATION(Phi) FROM (-a,0) to (a,0)
 ELEVATION(Phi) FROM (0,a) to (0,-a)
 ELEVATION(Phi) FROM (-a,-a) to (a,a)
 ELEVATION(Phi) FROM (a,-a) to (-a,a)
 END