{  3D_CAPACITOR.PDE  }
{
  This problem is an extension of "3D_Extrusion_Spec.PDE", and shows
  a capacitor formed by two metal strips of different size separated
  by a sheet of dielectric.
}
 
TITLE '3D Capacitor'
 
COORDINATES
  CARTESIAN3
 
SELECT
   alias(x) = "X(mm)"
   alias(y) = "Y(mm)"
   alias(z) = "Z(mm)"
  PAINTED
 
VARIABLES
  V
 
DEFINITIONS
  Kdiel= 80.1
  Kmetal=1e6
  KSiO2=3.9
  K = Kdiel              { default to Kdiel }
  V0 = 0
  V1 = 0.01
  Eps0 = 8.854e-12              { Farads/M }
  Eps0mm = 0.001*Eps0  { Farads/mm }  {fixed 1/10/03 }
  W = integral(0.5*K*eps0mm*grad(V)^2)  { Stored Energy }
  C = 1.0e6*2*W/(V1-V0)^2       { Capacitance in microFarads }
 
EQUATIONS
  DIV(K*GRAD(V)) = 0
 
EXTRUSION
  SURFACE       "Bottom"                        Z=0
    LAYER       "Bottom SiO2"
  SURFACE       "Bottom SiO2 - Metal"            Z=0.001
    LAYER       "Bottom Metal"
  SURFACE       "Bottom Metal - Dielectric"     Z=0.002
    LAYER       "Dielectric"
  SURFACE       "Top"                           Z=0.005
 


 BOUNDARIES
  SURFACE "Bottom" Natural (V)=0
  SURFACE "Top" Natural (V)=0
  REGION 1                          { this is the outer boundary of the system }
      LAYER "Dielectric" K = Kdiel  { all other layers default to Kair }
      START(0,0)
      LINE TO (0.022,0)  TO (0.022,0.125)  TO(0,0.125)  to close
 
 LIMITED REGION 2     { the larger bottom plate }
      LAYER "Bottom Metal" K = Kmetal
      
      START(0.001,0)
      LINE TO (0.004,0)
      LAYER "Bottom Metal" VALUE(V)=V1
      Line TO (0.004,0.125) TO (0.001,0.125) to close

     
 
        START(0.007,0)
        LINE TO (0.010,0) 
        LAYER "Bottom Metal" VALUE(V)=V0 
        LINE TO (0.010,0.125)
        LINE TO (0.007,0.125)
        LINE to close
    
      START(0.013,0)
      LAYER "Bottom Metal" VALUE(V)=V1   
      LINE TO (0.016,0)
      Line TO (0.016,0.125) TO (0.013,0.125) to close

     
 
      START(0.019,0)
      LAYER "Bottom Metal" VALUE(V)=V0  LINE TO (0.019,0.125)
     LINE TO (0.022,0.125)  LINE TO (0.022,0)
      LINE to close
 
   REGION 3     {the bottom SiO2}
      LAYER "Bottom SiO2" K = KSiO2
      Mesh_spacing = 0.005
      START(0,0)
      LINE TO (0.022,0) TO (0.022,0.125)
      LINE TO (0,0.125)
      LINE to close
   
   REGION 3  {the top dielectric}
   LAYER "Dielectric" K=Kdiel
   Mesh_spacing = 0.002
   START(0,0)
   LINE TO (0.022,0) TO (0.022,0.125)
   LINE TO (0,0.125)
   LINE to close

 
MONITORS
  CONTOUR(V) ON Y=0.005
PLOTS
  GRID(X,Z)  ON Y=0.050
  CONTOUR(V) ON X=0.010  REPORT(C) as "Capacitance(uF)"
  CONTOUR(V) ON Y=0.010  REPORT(C) as "Capacitance(uF)"
  CONTOUR(V) ON Z=0.002  REPORT(C) as "Capacitance(uF)"
  CONTOUR(1/K) ON Y=0.050 as "Material"
 
 
END