Natural condition with several variab... Log Out | Topics | Search
Moderators | Register | Edit Profile

FlexPDE User's Forum » User Postings » Natural condition with several variables « Previous Next »

Author Message
Top of pagePrevious messageNext messageBottom of page Link to this message

Mai Van Phu (riche)
New member
Username: riche

Post Number: 1
Registered: 06-2006
Posted on Tuesday, June 20, 2006 - 02:23 pm:   

Hello Dr Nelson,

I have an important question with Natural condition in Cylinrical Coordinates ('Z','R') with a axy-symetric geometric object.

My equation to resolve is: curl(m*curl(A))-A=0 written in term of componants ( Ar, Atheta, Az).

To obtain the NATURAL condition, I have used integration by part applied to the term curl(m*curl(A)). As result, the componant which correspond to Natural condition appears:

Nartural componant: n x (m*curl(A))*2*pi*r
With nr^2 + ntheta^2 + nz^2 = n^2 , n is the unit vector normal .
So:
Componant r: m*nz*(dAr/dr-dAz/dz) =...
Componant theta: m*1/r* ( nz*(d(r*Atheta)/dz - nr*(d(r*Atheta)/dr) ) =...
Componant z: m*nr*(dAr/dr-dAz/dz) =...

My questions is that: What does mean NATURAL(..) in this case? In fact, we have not only one variable in (..), but Ar, Az or Atheta altogether .

(usualy, we meet in other cases very simple, for example: Natural(Atheta)=… , which comes from: n*grad(Atheta) )

I have tried to set a new variable M= (dAr/dr-dAz/dz) and say: Value(M)=…. instead of Natural (dAr/dr-dAz/dz) ?? or something like that. But it doesn’t work.

Could you help me

Thank you so much.

Riche.






Top of pagePrevious messageNext messageBottom of page Link to this message

Robert G. Nelson (rgnelson)
Moderator
Username: rgnelson

Post Number: 637
Registered: 06-2003
Posted on Thursday, June 22, 2006 - 06:23 pm:   

As pointed out in the documentation of Natural BC's, the Natural defines the value of the integrand of the surface terms arising from integrating second order terms by parts.

Applied to the term curl(F), with F a vector, integration by parts yields the Curl Theorem
Vol_Integral(curl(F)dV) = Surf_Integral(n x F)dS)

So the meaning of the Natural of a curl equation is the value of the quantity (n x F) on the surface, applied componentwise to the component equations.

This is directly compatible with Maxwell's equations, which require continuity of the tangential component of H at material interfaces.





Top of pagePrevious messageNext messageBottom of page Link to this message

Robert G. Nelson (rgnelson)
Moderator
Username: rgnelson

Post Number: 638
Registered: 06-2003
Posted on Thursday, June 22, 2006 - 07:04 pm:   

PS
See our "Applications Manual" for more discussion of magnetic field problems. It is available for free download from our bookstore page at www.pdesolutions.com/bookstore.html
Top of pagePrevious messageNext messageBottom of page Link to this message

Philip (riche)
New member
Username: riche

Post Number: 2
Registered: 06-2006
Posted on Thursday, July 27, 2006 - 01:39 pm:   

Hello Dr Nelson,

Thank you for your previous help since longtimes

I have a question now about MESH EXPORT. I would like to transfer the SAME MESH of a file PDE ( after working of first file ) into another application of this file ( when I change a parameter in defintion). In other word, I want to save the mesh. I have tried 2 exemples: TRANSFER_out.PDE and TRANSFER_IN.PDE in the package "Applications Manual". But I find that they don’t give the SAME MESH.

Finaly, I want to do a ratio of results between 2 applications, for exemple: (Elevation of Temp of first application / Temps of second).

What can I do in this case. Maybe another command ?

Thank you,
Mai



{
This example uses a modification of the sample problem HEATBDRY.PDE
to illustrate the use of the TRANSFER output function. Temperatures
calculated here are transferred as input to the stress calculation
TRANSFER_IN.PDE }


title "Coolant Pipe Heatflow"

Variables
Temp(range=0,1)

definitions
K = 1
source = 4
Tzero = 0
flux = -K*grad(Temp)

equations
div(K*grad(Temp)) + source = 0

boundaries
Region 1
natural(Temp)=0
start "OUTER" (0,0)
line to(1,0)

natural(Temp)=0
arc (center=0,0) to (0,1)

natural(Temp)=0
line to finish

natural(Temp)=Tzero-Temp
start "INNER" (0.4,0.2)
arc (center=0.4,0.4)
to (0.6,0.4)
to (0.4,0.6)
to (0.2,0.4)
finish

monitors
contour(Temp)

plots
grid(x,y)
contour(Temp)
surface(Temp)
vector(-K*dx(Temp),-K*dy(Temp)) as "Heat Flow"
contour(source)
elevation(normal(flux)) on "outer" range(-0.08,0.08)
report(bintegral(normal(flux),"outer")) as "bintegral"
elevation(normal(flux)) on "inner" range(1.95,2.3)
report(bintegral(normal(flux),"inner")) as "bintegral"

{ HERE IS THE TRANSFER OUTPUT COMMAND: }
transfer(Temp) file="transfer.dat"

end 15317




{
This problem demonstrates the use of the TRANSFER facility to import
temperatures from TRANSFER_OUT.PDE as the source of thermal expansion
driving a stress calculation.

TRANSFER_OUT.PDE must be run before running this problem.
}


Title 'Testing the TRANSFER input function'

select
painted { paint all contour plots }

variables
U
V

definitions
nu = 0.3 { define Poisson's Ratio }
E = 21 { Young's Modulus x 10**-11 }
G = E/(1-nu**2)
C11 = G
C12 = G*nu
C22 = G
C33 = G*(1-nu)/2

alpha = 1e-3
b = G*alpha*(1+nu)

{ HERE IS THE TRANSFER INPUT FUNCTION: }
transfer('transfer.dat',Temp)

Sxx = C11*dx(U) + C12*dy(V) - b*Temp
Syy = C12*dx(U) + C22*dy(V) - b*temp
Sxy = C33*(dy(U) + dx(V))

initial values
U = 0
V = 0

equations
dx[Sxx] + dy(Sxy) = 0
dy[Syy] + dx(Sxy) = 0

constraints
integral(u) = 0
integral(v) = 0
integral(dx(v)-dy(u)) = 0


boundaries
Region 1
start "OUTER" (0,0)
natural(U)=0 value(V)=0
line to(1,0)
natural(U)=0 natural(V)=0 { free outer boundary }
arc (center=0,0) to (0,1)
value(U)=0 natural(V)=0
line to finish

natural(U)=0 natural(V)=0 { free inner boundary }
start "INNER" (0.4,0.2)
arc (center=0.4,0.4)
to (0.6,0.4)
to (0.4,0.6)
to (0.2,0.4)
finish

monitors
grid(x+100*U,y+100*V)

plots
contour(Temp)
grid(x+100*U,y+100*V)
vector(U,V) as "Displacement"
contour(U) as "X-Displacement"
contour(V) as "Y-Displacement"
contour(Sxx) as "X-Stress"
contour(Syy) as "Y-Stress"
surface(Sxx) as "X-Stress"
surface(Syy) as "Y-Stress"

end 5535




Top of pagePrevious messageNext messageBottom of page Link to this message

Robert G. Nelson (rgnelson)
Moderator
Username: rgnelson

Post Number: 665
Registered: 06-2003
Posted on Friday, July 28, 2006 - 01:38 am:   

Any TRANSFER output writes all the mesh data.

On input, TRANSFER creates a secondary mesh in which the input data can be interpolated. It does not map the input mesh onto the computation mesh.

In order to force FlexPDE to use the imported mesh as the computation mesh, you must import using the TRANSFERMESH command.

See all the TRANSFER... listings in the Help Index.
Top of pagePrevious messageNext messageBottom of page Link to this message

Philip (riche)
Member
Username: riche

Post Number: 4
Registered: 06-2006
Posted on Monday, July 31, 2006 - 07:40 am:   

Dr Nelson,
I am using flex PDE version 2.20d 3D. I can use tranfer but not transferMESH. I think that my problem is here. So, can I resolve it.

Thank you for your help.
Best Regard,
Mai

Add Your Message Here
Post:
Username: Posting Information:
This is a private posting area. Only registered users and moderators may post messages here.
Password:
Options: Enable HTML code in message
Automatically activate URLs in message
Action:

Topics | Last Day | Last Week | Tree View | Search | Help/Instructions | Program Credits Administration